if(NOT DEFINED CMAKE_INSTALL_PREFIX)
    set(CMAKE_INSTALL_PREFIX "@CMAKE_INSTALL_PREFIX@")
endif()
set(layout --prefix "${CMAKE_INSTALL_PREFIX}" --destdir "$ENV{DESTDIR}")
set(keys bindir libdir includedir docdir licensedir examplesdir desktopdir pkgconfigdir)
set(dirs "@CMAKE_INSTALL_BINDIR@" "@CMAKE_INSTALL_LIBDIR@" "@CMAKE_INSTALL_INCLUDEDIR@" "@CMAKE_INSTALL_DOCDIR@"
    "@XTC_INSTALL_LICENSEDIR@" "@XTC_INSTALL_EXAMPLESDIR@" "@XTC_INSTALL_DESKTOPDIR@" "@XTC_INSTALL_PKGCONFIGDIR@")
foreach(index RANGE 0 7)
    list(GET keys ${index} key)
    list(GET dirs ${index} dir)
    if(NOT IS_ABSOLUTE "${dir}")
        set(dir "${CMAKE_INSTALL_PREFIX}/${dir}")
    endif()
    list(APPEND layout --${key} "${dir}")
endforeach()
if(XTC_UNINSTALL)
    set(operation uninstall)
    set(extra)
else()
    set(operation install)
    set(extra --build-dir "@XTC_INSTALL_BUILD_DIR@")
    if("@XTC_INSTALL_GUI@")
        list(APPEND extra --gui)
    endif()
    set(jack)
    if("@JACK_FOUND@" AND "@XTC_WITH_JACK@")
        set(jack jack)
    endif()
    list(GET dirs 1 libdir)
    list(GET dirs 2 includedir)
    foreach(key libdir includedir)
        if(NOT IS_ABSOLUTE "${${key}}")
            set(${key} "${CMAKE_INSTALL_PREFIX}/${${key}}")
        endif()
    endforeach()
    execute_process(COMMAND "@Python3_EXECUTABLE@" tools/pkgconfig.py --prefix "${CMAKE_INSTALL_PREFIX}"
        --libdir "${libdir}" --includedir "${includedir}" --jack "${jack}" --output "@XTC_INSTALL_BUILD_DIR@/xtc.pc"
        WORKING_DIRECTORY "@PROJECT_SOURCE_DIR@" COMMAND_ERROR_IS_FATAL ANY)
endif()
execute_process(COMMAND "@Python3_EXECUTABLE@" "tools/${operation}.py" ${layout} ${extra}
    WORKING_DIRECTORY "@PROJECT_SOURCE_DIR@" COMMAND_ERROR_IS_FATAL ANY)